test_triang.f

Go to the documentation of this file.

C> @file tests/test_triang.f
C> Unit test of GRIDMAN_GRID2D_TRIANG
C GRIDMAN, grid managment library. Author: Vladislav Kotov, v.kotov@fz-juelich.de
 
!    Copyright (c) 2017  Forschungszentrum Juelich GmbH
!                        Vladislav Kotov 
!
!    This file is part of GRIDMAN.
!
!    GRIDMAN is free software: you can redistribute it and/or modify
!    it under the terms of the GNU General Public License as published by
!    the Free Software Foundation, either version 3 of the License, or
!    (at your option) any later version.
!
!    GRIDMAN is distributed in the hope that it will be useful,
!    but WITHOUT ANY WARRANTY; without even the implied warranty of
!    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
!    GNU General Public License for more details.
!
!    You should have received a copy of the GNU General Public License
!    along with GRIDMAN.  If not, see <http://www.gnu.org/licenses/>.

      PROGRAM test_triang
      USE gridman
      USE gridman_lib
      IMPLICIT NONE

      INTRINSIC abs,sum

      TYPE(gridman_grid) :: grid,tria
      REAL(GRIDMAN_DP),ALLOCATABLE :: vol(:),vol0(:),volt(:),
     r                                sarea(:),sareat(:)
      REAL(GRIDMAN_DP) :: v,vt
      INTEGER(GRIDMAN_SP) :: ie,icell,icell0 
      INTEGER :: ierr,res


      CALL grid_example4(grid,ierr)
      IF(ierr.NE.0) stop "TEST_TRIANG TERMINATED"

      gridman_check=.true.
      gridman_dbg=.false.

      CALL gridman_grid2d_triang(tria,grid,ierr)
      IF(ierr.NE.0) stop "TEST_TRIANG TERMINATED"
      CALL gridman_grid2d_triang(tria,grid,ierr)
      IF(ierr.NE.0) stop "TEST_TRIANG TERMINATED"

      ALLOCATE(vol(grid%NCELLS),vol0(grid%NCELLS),volt(tria%NCELLS))
      CALL gridman_grid2d_cylvolumes(grid,vol,ierr)
      IF(ierr.NE.0) stop "TEST_TRIANG TERMINATED"
      CALL gridman_grid2d_cylvolumes(tria,volt,ierr)
      IF(ierr.NE.0) stop "TEST_TRIANG TERMINATED"
  
      v=sum(vol)
      vt=sum(volt)
      IF(abs(v-vt).GT.gridman_tol) THEN
       WRITE(*,*) "ERROR in GRIDMAN_GRID2D_TRIANG ",
     w            " mismatch of volumes"
       WRITE(*,*) " V, VT ",v,vt
       stop "TEST_TRIANG TERMINATED"
      END IF  
   
      ALLOCATE(sarea(grid%NEDGES),sareat(tria%NEDGES))
      CALL gridman_grid2d_cylareas(grid,sarea,ierr)
      IF(ierr.NE.0) stop "TEST_TRIANG TERMINATED"
      CALL gridman_grid2d_cylareas(tria,sareat,ierr)
      IF(ierr.NE.0) stop "TEST_TRIANG TERMINATED"

C 
C     TEST INDICES 
C
C     EDGE INDEX
      IF(tria%EDGEINDEX(1)%NELEMENTS.NE.grid%NEDGES) THEN
       WRITE(*,*) "ERROR in GRIDMAN_GRID2D_TRIANG: ",
     w            "the generated edge index is wrong"
       WRITE(*,*) " NELEMENTS, NEDGES ",
     w              tria%EDGEINDEX(1)%NELEMENTS,grid%NEDGES
       stop "TEST_TRIANG TERMINATED"
      END IF 
      CALL gridman_index_compare(grid%EDGEINDEX(1),
     c                           tria%EDGEINDEX(1),res,ierr)   
      IF(ierr.NE.0) stop "TEST_TRIANG TERMINATED"
      IF(res.NE.0) THEN
       WRITE(*,*) "ERROR in GRIDMAN_GRID2D_TRIANG: ",
     w            "old and new indices must be equal"
       stop "TEST_TRIANG TERMINATED"
      END IF

      CALL gridman_index_compare(grid%EDGEINDEX(2),
     c                           tria%EDGEINDEX(2),res,ierr)   
      IF(ierr.NE.0) stop "TEST_TRIANG TERMINATED"
      IF(res.NE.0) THEN
       WRITE(*,*) "ERROR in GRIDMAN_GRID2D_TRIANG: ",
     w            "old and new indices must be equal"
       stop "TEST_TRIANG TERMINATED"
      END IF

C     CELL INDEX
      IF(tria%CELLINDEX(1)%NELEMENTS.NE.tria%NCELLS) THEN
       WRITE(*,*) "ERROR in GRIDMAN_GRID2D_TRIANG: ",
     w            "the generated cell index is wrong"
       WRITE(*,*) " NELEMENTS, NCELLS ",
     w              tria%EDGEINDEX(1)%NELEMENTS,tria%NCELLS
       stop "TEST_TRIANG TERMINATED"
      END IF
      vol0=0.
      DO ie=1,tria%CELLINDEX(1)%NELEMENTS
       icell=tria%CELLINDEX(1)%INDEXES(0,ie) 
       icell0=tria%CELLINDEX(1)%INDEXES(1,ie)  
       vol0(icell0)=vol0(icell0)+volt(icell)
      END DO 
      DO icell=1,grid%NCELLS
       IF(abs(vol(icell)-vol0(icell)).GT.gridman_tol) THEN
        WRITE(*,*) "ERROR in GRIDMAN_GRID2D_TRIANG: ",
     w             "incorrect cell index - mismatch of volumes"
        WRITE(*,*) " ICELL0, VOL, VOL0 ",icell,vol(icell),vol0(icell)
        stop "TEST_TRIANG TERMINATED"
       END IF
      END DO
      CALL gridman_index_compare(tria%CELLINDEX(1),
     c                           tria%CELLINDEX(2),res,ierr)   
      IF(ierr.NE.0) stop "TEST_TRIANG TERMINATED"
      IF(res.NE.0) THEN
       WRITE(*,*) "ERROR in GRIDMAN_GRID2D_TRIANG: ",
     w            "cell indices must be equal"
       stop "TEST_TRIANG TERMINATED"
      END IF

      CALL gridman_grid_write(grid,'grid.grd',ierr) 
      IF(ierr.NE.0) stop "TEST_TRIANG TERMINATED"

      CALL gridman_grid_write(tria,'tria.grd',ierr) 
      IF(ierr.NE.0) stop "TEST_TRIANG TERMINATED"

      WRITE(*,*) "TEST_TRIANG COMPLETED"

      END PROGRAM test_triang